***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*May 17, 2024                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt PEC3824CS-AU 1 2
.param
+vc0 = 1.000e-10		 vc1 = 5.005e-12   	 vc2 = 0.950	   vc3 = 1.081e-14		 vc4 = 1.985e-1
+tc1 = 2.131e-2		 tc2 = 2.301e-2		 tc3 = 8.455e-3      tc4 = 6.382e-2
.func irexp(v) {(vc0+vc1*v**vc2)*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))+(vc3*exp(vc4*v))*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
d1 1 C zener
g1 C 1 value = {irexp(v(C,1))}
d2 2 C zener
g2 C 2 value = {irexp(v(C,2))}
.model zener d
***** flag parameter *****
+level = 1                     
***** dc model parameter *****
+ is = 1e-15		   n = 1	        rs = 1e-4
+ibv = 1e-3		        nbv = 1	        bv = 29.8			
***** capacitance parameter *****
+cjo = 1.581e-11		   m = 2.178e-1		  vj = 7.363e-1
+ fc = 0.5
***** temperature coefficient *****
+tnom = 25	        eg = 0.3	        xti = 3
+trs1 = 1e-3		tbv1 = 4.909e-4		tbv2 = 1.309e-6
.ends PEC3824CS-AU
*$
